API Questions - Printable Version

Code: (Select All)
DEFLNG A-Z



CONST MIIM_STATE = &H1

CONST MIIM_ID = &H2

CONST MIIM_TYPE = &H10

CONST MFT_SEPARATOR = &H800

CONST MFT_STRING = &H0

CONST MFS_ENABLED = &H0

CONST MFS_CHECKED = &H8



CONST HWND_TOPMOST = -1

CONST HWND_NOTOPMOST = -2

CONST SWP_NOMOVE = &H2

CONST SWP_NOSIZE = &H1

'-----------------------------------------------------------------------------------



TYPE MENUITEMINFO

    cbSize AS LONG

    fMask AS LONG

    fType AS LONG

    fState AS LONG

    wID AS LONG

    hSubMenu AS LONG

    hbmpChecked AS LONG

    hbmpUnchecked AS LONG

    dwItemData AS _OFFSET

    dwTypeData AS _OFFSET

    cch AS LONG

END TYPE



DECLARE LIBRARY

    FUNCTION FindWindow& (BYVAL ClassName AS _OFFSET, WindowName$) ' To get hWnd handle

END DECLARE



DECLARE DYNAMIC LIBRARY "user32"

  FUNCTION CreateMenu& ()

  FUNCTION DrawMenuBar (BYVAL hWnd&)

  FUNCTION SetMenu& (BYVAL hWnd&, BYVAL hMenu&)

  FUNCTION InsertMenuItemA& (BYVAL hMenu&, BYVAL uItem&, BYVAL fByPosition&, BYVAL lpmii AS _OFFSET)

  FUNCTION GetMenuItemCount& (BYVAL hMenu&)

  FUNCTION GetMenuItemInfoA& (BYVAL hMenu&, BYVAL uItem&, BYVAL fByPosition&, BYVAL lpmii AS _OFFSET)

END DECLARE



DIM hWnd AS LONG

DIM hMenu AS LONG

DIM MenuItem AS MENUITEMINFO, BlankMenuItem AS MENUITEMINFO

DIM TypeData AS STRING * 1000



_TITLE "Menu bar API demo"

hWnd = _WINDOWHANDLE 'FindWindow(0, "Menu bar API demo" + CHR$(0))



hMenu = CreateMenu: BlankMenuItem.cbSize = LEN(BlankMenuItem)



COLOR 7, 1: CLS



'Add a separator bar

count = GetMenuItemCount(hMenu): PRINT "MenuItemCount:"; count

MenuItem = BlankMenuItem

MenuItem.fMask = MIIM_ID OR MIIM_TYPE

MenuItem.fType = MFT_SEPARATOR

MenuItem.wID = count

IF InsertMenuItemA(hMenu, count, 1, _OFFSET(MenuItem)) THEN PRINT "Successfully added menu item!" ELSE PRINT "Failed to add menu item!": END



'Add a button

MenuItem = BlankMenuItem

count = GetMenuItemCount(hMenu): PRINT "MenuItemCount:"; count

MenuItem.fMask = MIIM_STATE OR MIIM_ID OR MIIM_TYPE

MenuItem.fType = MFT_STRING

MenuItem.fState = MFS_ENABLED

MenuItem.wID = count

TypeData = "&Fire Laser!" + CHR$(0)

MenuItem.dwTypeData = _OFFSET(TypeData)

MenuItem.cch = LEN(MenuItem.dwTypeData)

MyButton = MenuItem.wID

IF InsertMenuItemA(hMenu, count, 1, _OFFSET(MenuItem)) THEN PRINT "Successfully added menu item!" ELSE PRINT "Failed to add menu item!": END



IF SetMenu(hWnd, hMenu) THEN PRINT "Successfully set menu!": PRINT "Menu handle is:"; hMenu ELSE PRINT "Failed to set menu!": END



DO: _LIMIT 70

    prev_state = new_state

    ok = GetMenuItemInfoA(hMenu, MyButton, 1, _OFFSET(MenuItem))

    new_state = MenuItem.fState AND 128

    IF prev_state = 0 AND new_state <> 0 THEN PRINT "Ouch! ";

LOOP WHILE INKEY$ = ""