C++ types > QB64 types: do we have an equivalent QB64PE page?

' /////////////////////////////////////////////////////////////////////////////

' FROM:



' vba - Extract URL From Excel Hyperlink Formula - Stack Overflow

' https://stackoverflow.com/questions/32230657/extract-url-from-excel-hyperlink-formula



' Excel VBA to extract Hyperlink from Hyperlink Formula - Super User

' https://superuser.com/questions/1313339/excel-vba-to-extract-hyperlink-from-hyperlink-formula



Public Function GetHyperLinkAddress(ByVal Target As Excel.Range) As String

    Dim RoutineName As String:: RoutineName = "GetHyperLinkAddress"

    Dim sFormula As String

    Dim sExpression As String

    Dim iStart As Long

    Dim iPos As Long

    Dim iEnd As Long

    Dim sURL As String

    Dim sSubAddress As String

    Dim sFind As String

    

    'Set Target = ActiveCell

    sURL = ""

    

    On Error Resume Next ' handle errors manually

    

    If Target.Hyperlinks.Count > 0 Then

        sURL = Target.Hyperlinks(1).Address

        sSubAddress = Target.Hyperlinks(1).SubAddress

        If Len(sSubAddress) > 0 Then

            sURL = sURL & "#" & sSubAddress

        End If

    ElseIf Target.HasFormula Then

        sFormula = Target.Formula

        sFind = "HYPERLINK("

        iPos = InStr(1, sFormula, sFind, vbTextCompare)

        If (iPos > 0) Then

            iEnd = InStr(iPos + 1, sFormula, ",", vbTextCompare)

            If (iEnd > 0) Then

                iStart = iPos + Len(sFind)

                sExpression = Mid(sFormula, iStart, iEnd - iStart)

                sURL = Evaluate(sExpression)

            End If

        End If

    End If

    

    If Err.Number <> 0 Then

        Debug.Print CStr(Now) & " " & RoutineName & " failed with error #" & CStr(Err.Number) & ": " & Err.Description

        Err.Clear

        sURL = ""

    End If

    

    On Error Goto 0 ' resume automatic error handling

    

    GetHyperLinkAddress = sURL

End Function ' GetHyperLinkAddress



' /////////////////////////////////////////////////////////////////////////////



Public Function GetURL(ByVal Target As Excel.Range) As String

    Application.Volatile

    GetURL = GetHyperLinkAddress(Target)

End Function ' GetURL