(05-20-2025, 11:21 PM)PhilOfPerth Wrote: I have never created a Function, but always used Sub for repeated operations. I'm trying to find how to create and apply Functions, and what, if any, are their advantages (in my SIMPLE programmes) over Subs. I've created these few lines to experiment, but get no results from the Function.

Code: (Select All)

Common Shared x, x$

x = 5: x$ = "ABC"

Print "Checkfunction returns";
Print CheckFunction$(x, x$)

CheckSub
Print "CheckSub returns"; x, x$

Function CheckFunction$ (x, x$)
    x = x * 3: x$ = x$ + "DEF"
End Function

Sub CheckSub
    x$ = x$ + x$
    x = x + x
End Sub

 What am I doing wrong? 

(05-20-2025, 11:34 PM)ahenry3068 Wrote:

(05-20-2025, 11:21 PM)PhilOfPerth Wrote: I have never created a Function, but always used Sub for repeated operations. I'm trying to find how to create and apply Functions, and what, if any, are their advantages (in my SIMPLE programmes) over Subs. I've created these few lines to experiment, but get no results from the Function.

Code: (Select All)

Common Shared x, x$

x = 5: x$ = "ABC"

Print "Checkfunction returns";
Print CheckFunction$(x, x$)

CheckSub
Print "CheckSub returns"; x, x$

Function CheckFunction$ (x, x$)
    x = x * 3: x$ = x$ + "DEF"
End Function

Sub CheckSub
    x$ = x$ + x$
    x = x + x
End Sub

 What am I doing wrong? 

Your using function wrong. 


x = 3
print Cubed(x)
end

function Cubed(X)

Cubed = X * X * X

end function

(05-21-2025, 12:39 AM)bplus Wrote: Functions can be used inside functions so you can do multiple functions in a single line of code.

A sub has to be run and the results run some place else.

Look at all the built in functions we use in the QB64 language, for instance LEN(myString$) or Mid$.

You can do this:

Function LastLetter$(mystring$)
LastLetter$ = Mid$(mystring$, Len(mystring$), 1)
End Function

Now LastLetter$ might be used in another function or sub or by main code.

(05-21-2025, 02:33 AM)SMcNeill Wrote: SUBS *do* something.   FUNCTIONS *return* something.     <--That's the difference between the two.

CLS, PRINT, BEEP, and SLEEP all *do* something for you; they're all SUBS.  CLS will clear the screen.  PRINT will print something to the screen.  BEEP makes your wife go crazy at 2 AM. SLEEP, contrary to the name doesn't help you cure insomnia....

On the other hand, COS, ABS, INT, and RND are all FUNCTIONS, as they return *something* to us.  COS returns the cosine value of the angle we give it.   ABS returns the absolute value of a number.  INT tells you what someone's  IQ is, and RND is good for random pickup lines at a bar..   (Or something like that.  )

To use a function, you need two basic things:

1) To give the function a NAME
2) To assign a value to that function's NAME before exiting the function

FUNCTION foo&
    foo& = 3
END FUNCTION

Function Steve$
  Steve$ = "Steve is Awesome"
END FUNCTION

Notice that the function name is important in marking what TYPE of return value we want.  foo& is a LONG.  Steve$ is a STRING.  It's that simple to make your function.

Parameters are simply passed so that you can do something more useful than what I'm doing above with those pitiful functions. 

Function AddString$ (first$, second$)
   AddString$ =  first$ + " " + second$
End Function

And then to make use of it is to either assign it to a return value, or else use it as an operation for a SUB.

MyName$ = AddString$("Steve","McNeill")
PRINT MyName$

Or just: PRINT  AddString$("Steve","McNeill")

The first MyName$ is assigning the return to the variable MyName$.  The second is sending it to a SUB to do something directly.  (Print, in this case.)


That's all there is to it.  Nothing complex or complicated to see here.