Quote:If anyone is using a dark mode IDE color theme for the IDE, then please share.

Quote:Scheme1$=VSCode|226226226115222227255043138255178034185237049157118137043045037010000020088088088170170170

Quote:I just discovered that on Linux cannot run a console-only program from the QB64 IDE if I want to use SYSTEM to end. It sucks.

(06-30-2023, 07:14 AM)RhoSigma Wrote:

(06-29-2023, 09:05 PM)a740g Wrote: If anyone is using a dark mode IDE color theme for the IDE, then please share.

Here is one that I created based on the default VSCode dark color theme.

Quote:Scheme1$=VSCode|226226226115222227255043138255178034185237049157118137043045037010000020088088088170170170

This is my current favorite, used in conjunction with the attached font.

Quote:Scheme1$=Broadcast|228224220034085170221068051238238068221136000051153034024024024036036036034136170170170170

The font is taken from https://int10h.org › fontlist , "The Ultimate Oldschool PC Font Pack".

(07-02-2023, 05:12 PM)bplus Wrote: You know what, I tested that edited version of a740g and lost my quickly tweaked settings but here is better:
Scheme1$=StarryNight|216216216069118226049186226000177226245128128000216128000000039078000128000088108170170170

'by mnrvovrfc 30-June-2023

'modified 14-July-2023



$CONSOLE:ONLY

OPTION _EXPLICIT



DIM sf(1 TO 20) AS STRING

DIM AS INTEGER i, rr, gg, bb, c, w, lc, insc, o, v

DIM afile$, bkpfile$, entry$, a$, e$, fe AS LONG



RANDOMIZE TIMER



afile$ = ENVIRON$("HOME") + "/bin/qb64pe/internal/config"

bkpfile$ = afile$ + "-bkp.ini"

afile$ = afile$ + ".ini"



FOR w = 1 TO 20

    a$ = "Scheme" + _TRIM$(STR$(w)) + "$=Random" + _TRIM$(STR$(w)) + "|"

    e$ = a$ + SPACE$(90)

    c = LEN(a$) + 1

    FOR i = 1 TO 10

        SELECT CASE i

            CASE 3, 4, 5

                rr = Rand(16, 96)

                gg = Rand(96, 160)

                bb = Rand(160, 255)

                IF Random1(2) = 1 THEN SWAP rr, gg

                IF Random1(2) = 1 THEN SWAP gg, bb

                IF Random1(2) = 1 THEN SWAP rr, bb

            CASE 7, 8, 9

                rr = Random1(97) - 1

                gg = Random1(49) - 1

                bb = Rand(32, 96)

                IF Random1(2) = 1 THEN SWAP gg, bb

                IF Random1(2) = 1 THEN SWAP rr, gg

                IF Random1(2) = 1 THEN SWAP rr, bb

            CASE ELSE

                DO

                    rr = Rand(64, 255)

                    gg = Rand(64, 255)

                    bb = Rand(64, 255)

                LOOP WHILE rr < 96 AND gg < 96 AND bb < 96

        END SELECT

        MID$(e$, c, 3) = Zeroes$(rr, 3)

        c = c + 3

        MID$(e$, c, 3) = Zeroes$(gg, 3)

        c = c + 3

        MID$(e$, c, 3) = Zeroes$(bb, 3)

        c = c + 3

    NEXT

    sf(w) = e$

NEXT



FOR w = 1 TO 20

    PRINT sf(w)

NEXT

PRINT

PRINT "Do you want to submit it into config-dot-ini?"

PRINT "PLEASE MAKE SURE OF THIS BECAUSE IT CANNOT BE UNDONE,"

PRINT "  IT COULD WRECK YOUR CONFIGURATION!"

PRINT "Proceed with adding to config.ini? Type "; CHR$(34); "YES"; CHR$(34)

LINE INPUT "  then press [ENTER] to confirm:", entry$

IF entry$ <> "YES" THEN SYSTEM



IF _FILEEXISTS(bkpfile$) THEN KILL bkpfile$



REDIM su(1 TO 1) AS STRING

lc = 0

fe = FREEFILE

OPEN afile$ FOR INPUT AS fe

DO UNTIL EOF(fe)

    LINE INPUT #fe, entry$

    IF LCASE$(LEFT$(entry$, 6)) = "scheme" AND INSTR(entry$, "$=Random") > 0 THEN

        o = INSTR(entry$, "$=Random")

        v = VAL(MID$(entry$, o + 8))

        IF v > 0 AND v <= 20 THEN _CONTINUE

    END IF

    lc = lc + 1

    REDIM _PRESERVE su(1 TO lc) AS STRING

    su(lc) = entry$

    IF entry$ = "[IDE COLOR SCHEMES]" THEN insc = lc

LOOP

CLOSE fe



NAME afile$ AS bkpfile$



fe = FREEFILE

OPEN afile$ FOR OUTPUT AS fe

FOR v = 1 TO lc

    PRINT #fe, su(v)

    IF v = insc THEN

        FOR w = 1 TO 20

            PRINT #fe, sf(w)

        NEXT

    END IF

NEXT

CLOSE fe

PRINT "MODIFIED: "; afile$

SYSTEM





FUNCTION Rand& (fromval&, toval&)

    DIM sg%, f&, t&

    IF fromval& = toval& THEN

        Rand& = fromval&

        EXIT FUNCTION

    END IF

    f& = fromval&

    t& = toval&

    IF (f& < 0) AND (t& < 0) THEN

        sg% = -1

        f& = f& * -1

        t& = t& * -1

    ELSE

        sg% = 1

    END IF

    IF f& > t& THEN SWAP f&, t&

    Rand& = INT(RND * (t& - f& + 1) + f&) * sg%

END FUNCTION



FUNCTION Random1& (maxvaluu&)

    DIM sg%

    sg% = SGN(maxvaluu&)

    IF sg% = 0 THEN

        Random1& = 0

    ELSE

        IF sg% = -1 THEN maxvaluu& = maxvaluu& * -1

        Random1& = INT(RND * maxvaluu& + 1) * sg%

    END IF

END FUNCTION



FUNCTION Zeroes$ (num AS LONG, numdig AS INTEGER)

    DIM b$, hx AS LONG, v AS LONG, sg AS INTEGER

    IF num < 0 THEN sg = -1: num = num * -1

    IF numdig < 0 THEN hx = 1: numdig = numdig * -1 ELSE hx = 0

    IF hx THEN

        b$ = HEX$(num)

    ELSE

        b$ = LTRIM$(STR$(num))

    END IF

    v = numdig - LEN(b$)

    IF v > 0 THEN b$ = STRING$(v, 48) + b$

    IF sg = -1 THEN b$ = "-" + b$

    Zeroes$ = b$

END FUNCTION

(07-14-2023, 08:32 PM)bplus Wrote: @mnrvovrfc gots to show screen shots