Vince's Corner Takeout

[vince]

I was aiming for a negative reputation, a nice red, but we're in too deep now

[bplus]

I was aiming for a negative reputation, a nice red, but we're in too deep now

And normally I'd aim to please but I don't think so now, it is too late, so sorry ;(

[vince]

new mod

Code: (Select All)

sw = 1024
sh = 480

dim shared m
m = 20

screen _newimage(sw, sh+1, 32)

do
    t = t + 0.02
    m = 25+20*sin(t)
    cls
    tri 0, sh, sw/2, 0, sw, sh, 10
    _display
    _limit 50
loop

sleep
system

sub tri(x1,y1, x2,y2, x3,y3, n)

    if n < 1 then exit sub

    'line (x1,y1)-(x2,y2)
    'line -(x3,y3)
    'line -(x1,y1)

    cx = (x1 + x3)/2
    cy = (y1 + y3)/2

    'line (cx, cy) - (x2, y2), _rgb(255,0,0)

    a = _atan2(y3-y1, x3-x1)
    d = sqr((cy - y2)^2 + (cx - x2)^2)
    w = d*tan(sqr(n)/m)
    nx = 1*(w)*cos(a)
    ny = 1*(w)*sin(a)
    line (cx, cy)-step(nx, ny),_rgb(255,255,0)
    line -(x2, y2),_rgb(255,255,0)
    line (cx, cy)-step(-nx, -ny),_rgb(255,255,0)
    line -(x2, y2),_rgb(255,255,0)
    line (x1,y1)-(x3,y3),_rgb(255,255,0)

    tri x1,y1, cx - nx, cy - ny, x2, y2, n - 1
    tri x3,y3, cx + nx, cy + ny, x2, y2, n - 1
end sub

[bplus]

Oh that's nice! Glad to see you're still kick'n! ;-)

[GareBear]

I'm with bplus, good to see have another one out. vince is me or you are doing a story between classic starfield and new mod? It looks like when you traveled to the end of the starfield you found this portal to go through. Does this means more programs to come? Hope you liked some of the fun links I done here. Just don't take this seriously.

[vince]

because I will lose this soon enough

Code: (Select All)

sw = 800
sh = 600
screen _newimage(sw, sh, 32)

x = sw/2
y = sh/2
vx = 0
vy = 0


do
    if _keydown(19200) then vx = vx - 3
    if _keydown(19712) then vx = vx + 3
    if _keydown(18432) then vy = vy - 3
    if _keydown(20480) then vy = vy + 3

    x = x + vx
    y = y + vy

    if vx > 0 then vx = vx - 1
    if vy > 0 then vy = vy - 1
    if vx < 0 then vx = vx + 1
    if vy < 0 then vy = vy + 1

    cls
    line (x, y) - step(100, 100), _rgb(255,255,0),bf

    _limit 30
    _display

loop until _keyhit = 27
system

[bplus]

Interesting don't see any jerkiness with acceleration using vx, vy.

Here is one I don't want to lose, now that I've got it figured out for minimal lines and processing:

Code: (Select All)

sw = 800: sh = 600
Screen _NewImage(sw, sh, 32)
x = sw / 2: y = sh / 2
Do
    Cls
    kh& = _KeyHit
    x = x + -5 * (kh& = 19200) * (x > 0) + 5 * (kh& = 19712) * (x < sw)
    y = y + -5 * (kh& = 18432) * (y > 0) + 5 * (kh& = 20480) * (y < sh)
    Line (x - 50, y - 50)-Step(100, 100), _RGB(255, 255, 0), BF
    _Limit 300 ' 10 is too choppy 30 OK? 300! doesn't seem 10 X's faster than 30
    _Display
Loop Until kh& = 27
System

How boring never allowed outside the box

You can replace all 5's will variable v for velocity and maybe for acceleration too if you want.

[vince]

fixed window resizing on my favourite game

[bplus]

love it. this is the most infuriating game in the universe.

Well I'd take my hacker skills and keep fixing it until it was fun!

[vince]

hair

Code: (Select All)

defdbl a-z

dim shared as integer sw, sh, mx, my, mb, mw



pi = 4*atn(1)



sw = 800

sh = 600



screen _newimage(sw, sh, 32)



n = 15

dim x(n), y(n)



for i=0 to n-1

    x(i) = sw/2

    y(i) = i*sh/n

next



r = 35

mw = r



do

    cls



    getmouse

    r = mw



    x(0) = mx

    y(0) = my

    for i=1 to n-1

        if ((x(i - 1) - x(i))^2 + (y(i - 1) - y(i))^2) > r*r then

            a = _atan2(y(i - 1) - y(i), x(i - 1) - x(i)) - pi

            x(i) = x(i - 1) + r*cos(a)

            y(i) = y(i - 1) + r*sin(a)

        end if

    next





    'preset (x(0), y(0))

    'for i=0 to n - 1

    '    line -(x(i), y(i)), _rgb(55,55,0)

    '    circle (x(i), y(i)), 3, _rgb(255,255,0)

    'next



    preset (x(0), y(0))



    dt = 0.001

    for t=0 to 1 step dt

        bx = 0

        by = 0    

        

        'dx = 0

        'dy = 0

        

        for i=0 to n - 1

            bin = 1

            for j=1 to i

                bin = bin*(n - j)/j

            next

        

            p = bin*((1 - t)^(n - 1 - i))*(t^i)

            bx = bx + p*x(i)

            by = by + p*y(i)

                          

            'q = bin*((1 - t)^(n - 2 - i))*(t^(i - 1))*(i - n*t + t)

            'dx = dx + q*x(i)

            'dy = dy + q*y(i)                

        next



        if abs(bx - ox)>1 and abs(by - oy)>1 then

            line -(bx, by), _rgb(255,0,0)



            ox = bx

            oy = by

        end if

        

        'm = sqr(dx*dx + dy*dy)

        'line -step(10*dx/m, 10*dy/m), _rgb(0,255,0)

    next

    line -(bx, by), _rgb(255,0,0)





    _display

    _limit 30

loop until _keyhit = 27

system





sub getmouse()

    do 

        mx = _mousex

        my = _mousey

        mb = _mousebutton(1)

        mw = mw - _mousewheel

    loop while _mouseinput

end sub