Anyone know how frostbite thresholds are calculated?

[SMcNeill]

Something small I was working on to go with my home weather system:

Code: (Select All)

SCREEN _NEWIMAGE(800, 600, 32)
$COLOR:32
PRINT "  ";
count = 1
FOR temp = 40 TO -45 STEP -5
    LOCATE , 4 * count
    PRINT temp;
    count = count + 1
NEXT
PRINT


FOR windspeed = 5 TO 60 STEP 5
    COLOR White, Black
    PRINT windspeed;
    COLOR Black, SkyBlue
    count = 1
    FOR temp = 40 TO -45 STEP -5
        wc& = WindChill(temp, windspeed)
        LOCATE , 4 * count
        count = count + 1
        SELECT CASE wc&
            CASE IS > -18: COLOR Black, LightBlue
            CASE IS > -32: COLOR White, SkyBlue
            CASE IS > -48: COLOR White, Blue
            CASE ELSE: COLOR White, Purple
        END SELECT

        PRINT wc&; " ";
    NEXT
    PRINT
NEXT

COLOR White, Black


FUNCTION WindChill& (temp AS _FLOAT, windspeed AS _FLOAT)
    WindChill = 35.74 + 0.6215 * temp - 35.75 * windspeed ^ 0.16 + 0.427 * temp * windspeed ^ 0.16
END FUNCTION

Now, as you can see, my chart matches the values from the chart here: WindChill (weather.gov)




Only issue is my color values don't match.  Anyone know why -62 windchills are light blue at the top of the chart, but then are purple at the bottom?  If the implied temperature is -52 in both cases, shouldn't frostbite occur at the same time?  Isn't that basically what windchill is for -- to give an equal representation of what the temperature would feel like it the wind wasn't blowing?

How's that frostbite time calculated?  Anyone have a clue, just so I can get my color scheme to match?