QB64-PE v4.2.0 is now available

[doppler]

I am happy to see we did not loose Fellippe as a provider.
"- #627 - Fix IDE error when loading large source file - @FellippeHeitor"

I am re-posting a little up-grader program from long ago I made (version qb64pe 3.x something).  To assist in times like now, when a new version arrives.
This a multi-file drop program.  Collect all your EXE's and drop into the program window.  Then open a command prompt window run the doit.cmd script.

I only assume your source files are in a qb64pe directory sub folder.  In my case it's qb64pe\my programs.  If not it's an easy tweak, start with lines 13, 20 and 21.
I hope you find this useful, it saves me from individual compiling of dozens of programs.
P.S. don't recompile qb64pe and qb64pe bas upgrader  and if you get a "hit any key to continue" just doit.  Not sure why but it happens, really shouldn't.

Code: (Select All)

_Title "QB64pe Bas Upgrader v1.0"
Width 80, 10
_ScreenMove 10, 10

Cls
'
' I always use q$ to use quotes, just how I am
Q$ = Chr$(34)
'
' define where sources are  <<< change variable to your directory >>>
' remember to slap a "\" to your source path end
'
source$ = "My Programs\"

'
' get home path
' noramlly this would be in the root of qb64pe
' screwy things could happen if it isn't
'
hp$ = Command$(0)
hp$ = Left$(hp$, _InStrRev(hp$, "\"))

' assume homepath + source is one path from here on out.

ChDir hp$

_AcceptFileDrop 'enables drag/drop functionality
Print "Drag the EXE file(s) and drop in this window... or x to exit"

Do
    _Limit 3
    x$ = InKey$
    If UCase$(x$) = "X" Then
        Cls
        Print "I don't plan to open a command prompt"
        Print "for you.  doit.cmd script is in " + hp$
        Print "folder. You can examime / execute / observe."
        hitenter
        System
    End If
Loop Until _TotalDroppedFiles <> 0

Open "doit.cmd" For Output As #1

Do
    Print
    f$ = _DroppedFile
    If f$ = "" Then Exit Do
    '
    ' take out all path info and test for source available.
    ' also scrap off extention
    '
    f$ = Right$(f$, Len(f$) - _InStrRev(f$, "\"))
    f$ = Left$(f$, Len(f$) - 4)
    Print "Using "; f$
    '
    ' ok do we have source bas ?
    '
    If _FileExists(hp$ + source$ + f$ + ".bas") = 0 Then
        Print "Sorry I can not compile the above file. The source does not"
        Print "exist in paths provided. Suggest exclude the file(s)"
        Print "next time in selection and drop again."
        hitenter
    End If
    '
    ' if you got this far a doit.cmd line can be generated
    '
    Print #1, hp$ + "qb64pe.exe -c " + Q$ + hp$ + source$ + f$ + ".bas" + Q$

Loop

Close
'
' another chance to do over or exit
'
Print "doit.cmd created and closed"
Print "Hit enter, followed by x"
Print "to exit or drop files again"
hitenter
Run

Sub hitenter
    Input "Hit <enter> to continue "; bad
End Sub