Calculate Lakhovsky antenna

[Rudy M]

Hello everybody,

At a trade show, I saw a Lakhovsky machine and heard the claim that the two antennas between which the chair is positioned were made according to the golden ratio. 
I immediately realized this wasn't true! 
After printing a small antenna on A4 paper, I could already see that it was linear and not according to the golden ratio. 
A bit of searching online confirmed my suspicion. 
You can find information at: 
https://lakhovsky.com/ 
https://www.hackster.io/mircemk/diy-simp...tor-be098c 

Whether the device works or is functional or not, I'd like to leave the discussion open here. 
I created this program to learn more about QB64 and for fun. 

The calculated values by this qb64 program are (more) accurate than 1 mm,
 measured on a photo of a Lakhovsky antenna, printed on an A4 sheet of paper,
and also in comparision with a table in his patent.

Possible extension: Switching between inch and mm (1mm = 0.039370079 inch)

Greetings, Rudy

Code: (Select All)

OPTION _EXPLICIT



'rem: For programming fun in QB64, or to reeele construct a Lakhovsky antenna.

'=============================================================================

'Basic sources: Lakhovsky's patent (machine) via Google.



'=======================================================================================

'Thanks to "Claude AI" for the basic idee of calculating and drawing concentric circles.

'=======================================================================================



'test

'variable phi# replaced by my own made variable Lak# = 1.272 ' (= square root of the golden ratio "Phi")

'The diameters of this listing cover 100% the information of "The Borderland Science Research Foundation",

'concerning Lakhovsky's Multi Wave Oscillator and Lakhovsky-antenna's  (and NOT the golden ratio "Phi").



'So... The claim of many people that Lakhovsky antenna are made following the golden ratio is nonsense!

'In reality Lackhovsky antenna are med on a LINEAIR arithmetic base (1.272)

'If You do'nt believe me: In this listing, change Lak#=1.272 to 1.618 (golden ratio)...

'and You shall see that the antenna never looks the same as the original Lakhovsky antenna in his patent.



_FULLSCREEN 'if You want a little screen unmark this statement and use Your own screen statements.

SCREEN 12

CLS



' Declare variables

DIM r1# ' Radius of first circle (outher circle, not the inner circle)

DIM Lak# ' = square root of the golden ratio

DIM GapCorrector#

DIM n% '  Circle number

DIM r#(40), d#(40), cr#(40) 'Radius, diameter and circemreferences

DIM d_min#

Lak# = 1.272 '= square root of phi (1.816)

GapCorrector# = 0.95 '(360 - 18 / 360) because each gap is 18 degrees of the circle

d_min# = 8 'Minumum circumref. of the little innercircle (ev. change to Your preference)

'          With value = 8 also circumref of +-10mm are calculated...)

DIM x%, max%

DIM x$



'According to Lakhovsky's patent, the diameter of radiators is reduced by the same factor,

'and there need to be a gap from 18 degrees in each radiator of 18 degrees.

DIM wd#(40) 'full diameter

DIM wl#(40) 'correction for the gap of 18 degrees



LOCATE 5, 10

PRINT "Concentric circles based on 1.272 = sqaure root of the golden ratio 1.618"

PRINT "The diameters of the radiators are calculated on the same manner!"

PRINT "------------------------------------------------------------------------------"

PRINT

PRINT "For practical use following data is also calculated:"

PRINT "1) Radius and Circumreferences"

PRINT "2) Circumreferences minus 18 degrees:"

PRINT "  To cut cupper wire or cupper pipes for the radiators, minus the gap."

PRINT "3) Diameters of radiatorwire: Not 100% critical"

PRINT "  (use 30 to 50% larger or smaller diameters without any problem)."

PRINT "4) Length of radiators (calculated minus the gap of 18 degrees)."

PRINT "5) Inner circle is made between +-12mm (+-1/2 inch) and 50mm (+-2 inch),"

PRINT "  according personal preference or material construction possibilitys."

PRINT "6) Gaps are made to produce many higher harmonics then input-frequency."

PRINT "  Antenna is mostly constructed on hard isolating plastic sheet as base."

PRINT "  Backsite of the sheet the gap is filled with the same radiatorwire"

PRINT "  or tube. Construction could also be with double cupperlayer printplate."

PRINT "-------------------------(Press <ENTER> please)---------------------------"

PRINT: PRINT



DO: x$ = INKEY$: _LIMIT 30: LOOP WHILE x$ = "" 'max 30 loops per second

CLS



'Give desired basic parameters

n% = 1

DO

  INPUT "Diameter of outher circle in mm  (0 = END) : "; d#(n%)

  IF d#(n%) = 0 THEN END

  EXIT DO

LOOP

DO

  PRINT "---------------------------------------------------------"

  PRINT "Tip: Give a standard diameter of coppertube or copperwire"

  PRINT "    Copper wire may be solid, woven or twisted"

  PRINT ""

  PRINT "    Minimum accepted copper-wire diameter: 1 mm (0 = stop)"

  INPUT "Wire-diameter outher radiator in mm, p.e. start with 10  (0 = END) : "; wd#(n%)

  IF wd#(n%) = 0 THEN END

  EXIT DO

LOOP

CLS



'calculate radius and diameters, circumferences of all circles

n% = 1

DO

  IF n% = 1 THEN

    r#(n%) = d#(n%) / 2 'Outher circle

    cr#(n%) = d#(n%) * _PI

    wl#(n%) = cr#(n%) * GapCorrector# 'radiatorlength minus the gap

  ELSE

    d#(n%) = d#(n% - 1) / Lak#

    IF d#(n%) < d_min# THEN n% = n% - 1: EXIT DO 'stop if to small to construct

    r#(n%) = d#(n%) / 2

    cr#(n%) = d#(n%) * _PI

    wd#(n%) = wd#(n% - 1) / Lak#

    wl#(n%) = cr#(n%) * GapCorrector#

  END IF

  n% = n% + 1

LOOP



'Info: For control purposes or to make a Lakhovsky antenna

PRINT "********************Lakhovsky antenna calculator ************************"

PRINT "*    Wirelength = circumref minus 18 degrees for the antenna-gap      *"

PRINT "*    Wirediameter = not critical (calc. with several wire-diam)        *"

PRINT "*    (For big outher radiators: Use standard diam. copper tube.        *"

PRINT "*-----------------------------------------------------------------------*"

PRINT "* nr  cir_rad.  cir_diam.  circumref  wirelength  gap-lenght  wirediam  *"

PRINT "*-----------------------------------------------------------------------*"

FOR x% = 1 TO n%

  PRINT "*";

  PRINT USING " ##"; x%;

  PRINT "  ";

  PRINT USING "#####.#"; r#(x%);

  PRINT "    ";

  PRINT USING "#####.#"; d#(x%);

  PRINT "  ";

  PRINT USING "######.#"; cr#(x%);

  PRINT "    ";

  PRINT USING "######.#"; wl#(x%);

  PRINT "    ";

  PRINT USING "######.#"; cr#(x%) - wl#(x%);

  PRINT "  ";

  PRINT USING "#####.#"; wd#(x%);

  PRINT "  *"

NEXT x%

PRINT "*************************************************************************"

SLEEP



' Draw concentric circles (possible correction: draw no circleline for the gap)

FOR x% = 1 TO n% ' Draw n% circles (or change n% to Your preference)

  'CIRCLE (column, row), radius%, [drawColor%][, startRadian!, stopRadian!] [, aspect!]

  CIRCLE (320, 240), r#(x%) ' Draw circle

NEXT x%



' Wait for key press

SLEEP

END