Another way to use Hardware Images and Transparency (alpha channel) for a PopUp Menu

[TempodiBasic]

Hi
@Pete
I have tried this way to accomplish the goal to have a PopUp menu and to use Hardware acceleration images for this and/or buttons.
here screenshots:

at start, button is hardware image, window is software image


showing popup menu: popup is software image, hover selection of mouse pointer is hardware image



overlapping popup and button: button appears as a shadow color in popup, just like if popup menu has a low grade of transparency (alpha channell about 30%)



here the code:

Code: (Select All)

 
Screen 0
_DisplayOrder _Software , _Hardware ' this says only what must be shown
Dim As Long Img1, Img2
Dim As Integer X, Y, Mb, Xm, Ym
 
Cls , 3
' here it creates a square to overlap menu to make the shadow of selection
Img1 = _NewImage(112, 16, 32)
_Dest Img1
Cls , _RGBA32(127, 205, 255, 125)
Img1 = _CopyImage(Img1, 33)
 
' here it creates the Button image
Img2 = _NewImage(100, 50, 32)
_Dest Img2
Cls , _RGBA32(127, 0, 255, 80)
Color _RGBA32(0, 0, 0, 80), _RGBA32(0, 0, 155, 0)
_PrintString (10, 17), "Click Here"
Img2 = _CopyImage(Img2, 33)
 
' inizialization and main loop
_Dest 0
Color 11, 3
X = 0
Y = 0
Xm = 0
Ym = 0
Mb = 0
Do
    Locate 1, 1: Print "Left click to show popup menu"; ' it shows help on first line of text
    _PutImage (300, 300), Img2, 0 ' button
    If _MouseInput Then
        X = _MouseX
        Y = _MouseY
        If _MouseButton(1) Then Mb = 1
        If _MouseButton(2) Then Mb = 2
    End If
    If Mb = 1 Then
        If X < 1 Or X + 13 > 80 Or Y < 1 Or Y + 3 > 24 Then
            Beep ' mouse's popup menu goes out of window's area
            Mb = 0
        Else
            ShowPopUp: Xm = X: Ym = Y: Mb = 0 ' popup menu
        End If
    End If
    If (X >= Xm And X <= Xm + 13) And (Y >= Ym And Y <= Ym + 3) Then
        _PutImage ((Xm - 1) * 8, (Y - 1) * 16), Img1, 0 ' hover / selection item of popup menu
    End If
    _Display
Loop Until Mb = 2
_FreeImage Img1
_FreeImage Img2
End
 
Sub ShowPopUp
    Shared X As Integer, Y As Integer
    Cls , 3
    Color 14, 1
    Locate Y, X
    Print "New.....Ctrl+N"
    Locate , X
    Print "Open....Ctrl+O"
    Locate , X
    Print "Close...Ctrl+X"
    Locate , X
    Print "Quit....Ctrl+Q";
    Color 11, 3
End Sub

One tip: you must select the right combination of color to get a good visual effect.

[Pete]

Hi my friend from Italia,

Smart! You figured out a way to mess with the hardware button transparency to give the optical illusion the software menu is floating over it, instead of under it, as would happen with no opacity!

Yes, I also used a hardware shadow effect to make my popup look 3-D., just like you used one to highlight menu choices.

Well this would only work in my application if I wasn't also using .png images. Well, maybe another set could be saved with opacity, I'm not sure. As far as my graphics buttons go, yes, they could be switched out to opaque ones when the popup comes up on the screen. It's not a bad effect, as it draws attention away from the main screen when the popup is open.

Amazing Steve didn't think of this.

+2 for thinking under the box!

Pete