'by mnrvovrfc 6-July-2023

OPTION _EXPLICIT



DIM AS INTEGER c, lsubj, j, plu

DIM prefx$, afile$, launchprog$, comd$, asubj$, ayear$, entry$

DIM fe AS LONG



prefx$ = "helparchorg-"

afile$ = prefx$ + "browser.txt"

IF NOT _FILEEXISTS(afile$) THEN

    PRINT "The web browser wasn't found! Aborting."

    END

END IF



fe = FREEFILE

OPEN afile$ FOR INPUT AS fe

DO UNTIL EOF(fe)

    LINE INPUT #fe, entry$

    entry$ = _TRIM$(entry$)

    IF entry$ <> "" AND launchprog$ = "" THEN

        launchprog$ = entry$

        EXIT DO

    END IF

LOOP

CLOSE fe



IF NOT _FILEEXISTS(launchprog$) THEN

    PRINT "The web browser wasn't found! Aborting."

    END

END IF



PRINT "Discovered web browser executable called:"

PRINT launchprog$



afile$ = prefx$ + "subject.txt"

IF NOT _FILEEXISTS(afile$) THEN

    afile$ = prefx$ + "category.txt"

END IF

IF _FILEEXISTS(afile$) THEN

    fe = FREEFILE

    OPEN afile$ FOR INPUT AS fe

    DO UNTIL EOF(fe)

        LINE INPUT #fe, entry$

        entry$ = _TRIM$(entry$)

        IF entry$ <> "" THEN lsubj = lsubj + 1

    LOOP

    CLOSE fe

    IF lsubj < 1 THEN

        PRINT "At least one entry required from input file!"

        END

    END IF

    REDIM subj(1 TO lsubj) AS STRING

    c = 0

    fe = FREEFILE

    OPEN afile$ FOR INPUT AS fe

    DO UNTIL EOF(fe)

        LINE INPUT #fe, entry$

        entry$ = _TRIM$(entry$)

        IF entry$ <> "" THEN

            c = c + 1

            subj(c) = entry$

        END IF

    LOOP

    CLOSE fe

ELSE

    lsubj = 1

    REDIM subj(1 TO lsubj) AS STRING

    subj(lsubj) = "electronic"

END IF



PRINT "*** archive-dot-org helper ***"

IF lsubj = 1 THEN

    PRINT: PRINT "There's only one category available: "; subj(1)

    asubj$ = subj(1)

ELSE

    PRINT: PRINT "Please choose your category."

    FOR j = 1 TO lsubj

        PRINT USING "(##)"; j;

        PRINT " "; subj(j)

    NEXT

    LINE INPUT entry$

    entry$ = _TRIM$(entry$)

    IF entry$ = "" THEN SYSTEM

    c = VAL(entry$)

    IF c > 0 AND c <= lsubj THEN

        asubj$ = subj(c)

    ELSE

        PRINT "Incorrect input given! Aborting."

        END

    END IF

END IF



PRINT: PRINT "Please choose the year of release."

FOR j = 2013 TO 2023

    PRINT USING "(####)"; j - 2012;

    PRINT " "; j

NEXT

LINE INPUT entry$

entry$ = _TRIM$(entry$)

IF entry$ = "" THEN SYSTEM

c = VAL(entry$)

IF c > 0 AND c < 12 THEN

    ayear$ = _TRIM$(STR$(c + 2012))

ELSE

    PRINT "Incorrect input given! Aborting."

    END

END IF



comd$ = launchprog$ + " 'https://archive.org/details/audio?and[]=year%3A%22" + ayear$ + _

"%22&and[]=mediatype%3A%22audio%22&and[]=subject%3A%22"

plu = INSTR(asubj$, "+")

IF plu > 0 THEN

    comd$ = comd$ + LEFT$(asubj$, plu - 1) + "%22&and[]=subject%3A%22" + MID$(asubj$, plu + 1) + "%22'"

ELSE

    comd$ = comd$ + asubj$ + "%22'"

END IF

SHELL _HIDE _DONTWAIT comd$

SYSTEM

comd$ = CHR$(34) + launchprog$ + CHR$(34) + " https://archive.org/details/audio?and[]=year%3A%22" + ayear$ + _

"%22&and[]=mediatype%3A%22audio%22&and[]=subject%3A%22"

plu = INSTR(asubj$, "+")

IF plu > 0 THEN

    comd$ = comd$ + LEFT$(asubj$, plu - 1) + "%22&and[]=subject%3A%22" + MID$(asubj$, plu + 1) + "%22"

ELSE

    comd$ = comd$ + asubj$ + "%22"

END IF

PRINT launchprog$

PRINT comd$

SLEEP

SHELL _HIDE _DONTWAIT comd$

(07-09-2023, 04:16 PM)grymmjack Wrote: If you wanted to you could detect the OS and then act accordingly I guess?

I know Linux/Mac needs the single quoted string because of shell expansion, but that made it try to open the string as a "file://" on Windows.

Really neat program, thank you for sharing.

Option Explicit

$NoPrefix

$Unstable:Http



$Console:Only



Title "Wayback Machine API"

ConsoleTitle "Enter Link"



Dim As String link

Do

    Cls

    Line Input "Link: ", link

Loop Until link <> ""



ConsoleTitle Title$ + " - " + link



link = "https://archive.org/wayback/available?url=" + link



Dim As Long hConn: hConn = OpenClient("HTTP:" + link)

If hConn < 0 And StatusCode(hConn) = 200 Then

    Dim As String buf, json

    Dim As Long length: length = LOF(hConn)

    While Not EOF(hConn)

        Get hConn, , buf

        json = json + buf

    Wend

    Dim As String available: available = Mid$(json, InStr(json, Chr$(34) + "available" + Chr$(34) + ": ") + Len(Chr$(34) + "available" + Chr$(34) + ": "))

    available = Mid$(available, 1, InStr(available, ",") - 1)

    If available = "true" Then

        Dim As String url

        url = Mid$(json, InStrRev(json, Chr$(34) + "url" + Chr$(34) + ": ") + 8)

        url = Mid$(url, 1, InStr(url, Chr$(34)) - 1)

        Shell Hide DontWait "start " + url

        Print "Opening in default browser..."

        GoTo exiting

    Else

        Print "URL not available on the Wayback Machine"

        GoTo exiting

    End If

    Close hConn

End If



exiting:

Dim As Long l: l = CsrLin

Dim As _Byte i

For i = 3 To 0 Step -1

    Locate l, 0

    Print "Exiting in"; i; "seconds..."

    Sleep 1

Next

System

'by Spriggsy

Option Explicit

$NoPrefix

$Unstable:Http



$Console:Only



Title "Wayback Machine API"

ConsoleTitle "Enter Link"



Dim As String link, ess, entry, dotwhat

'by mnrvovrfc: changed here so it's only necessary to put down the "fat part", and hint if the user prefers "secure" protocol

Cls

Line Input "Link: ", link

if link = "" then system

if lcase$(left$(link, 2)) = "s." then

    ess = "s"

    link = mid$(link, 3)

end if

print

print "What is the suffix?"

line input "(1) com; (2) org; (3) net; (4) none; (5) other:", entry

if entry = "" then system

if entry = "5" then

    line input "Please enter the suffix:", dotwhat

    if dotwhat = "" then system

    if left$(dotwhat, 1) = "." then dotwhat = mid$(dotwhat$, 2)

elseif entry = "1" then

    dotwhat = "com"

elseif entry = "2" then

    dotwhat = "org"

elseif entry = "3" then

    dotwhat = "net"

end if

link = "http" + ess + "://" + link

if entry <> "4" then link = link + "." + dotwhat



ConsoleTitle Title$ + " - " + link



link = "https://archive.org/wayback/available?url=" + link



Dim As Long hConn: hConn = OpenClient("HTTP:" + link)

If hConn < 0 And StatusCode(hConn) = 200 Then

    Dim As String buf, json

    Dim As Long length: length = LOF(hConn)

    While Not EOF(hConn)

        Get hConn, , buf

        json = json + buf

    Wend

    Dim As String available: available = Mid$(json, InStr(json, Chr$(34) + "available" + Chr$(34) + ": ") + Len(Chr$(34) + "available" + Chr$(34) + ": "))

    available = Mid$(available, 1, InStr(available, ",") - 1)

    If available = "true" Then

        Dim As String url

        url = Mid$(json, InStrRev(json, Chr$(34) + "url" + Chr$(34) + ": ") + 8)

        url = Mid$(url, 1, InStr(url, Chr$(34)) - 1)

$IF WIN THEN

        Shell Hide DontWait "start " + url

$ELSE

        Shell Hide DontWait "xdg-open " + url

$END IF

        Print "Opening in default browser..."

        GoTo exiting

    Else

        Print "URL not available on the Wayback Machine"

        GoTo exiting

    End If

    Close hConn

End If



exiting:

Dim As Long l: l = CsrLin

Dim As _Byte i

For i = 3 To 0 Step -1

    Locate l, 0

    Print "Exiting in"; i; "seconds..."

    Sleep 1

Next

System