Screen Savers

[SMcNeill]

Try this out: 

Code: (Select All)

_Title " Eye Candy #9B Closer (fullscreen)" ' b+ 2022-03-09

'fullscreen mod by Steve. 2025-04-17

DefDbl A-Z

xmax = _DesktopWidth: ymax = _DesktopHeight

Screen _NewImage(xmax, ymax, 32)

_ScreenMove 0, 0

xc = xmax / 2

yc = ymax / 2

diag = Sqr(xc * xc + yc * yc)

p2 = _Pi * 2

Dim colr(-100 To diag + 1000) As _Unsigned Long

Dim Shared cN, pR, pG, pB

While 1

    resetPlasma

    For i = -100 To diag + 1000

        colr(i) = Plasma~&

    Next



    ro = 950: s = 0

    While ro > -50 And _KeyDown(27) = 0

        k$ = InKey$

        If Len(k$) Then Exit While

        Cls

        For a = 0 To p2 / 64 Step p2 / (16 * 360)

            i = 50 * Sin(s) ' 2 * s or just s

            For r = 0 To diag

                PSet (xc + r * Cos(a), yc + r * Sin(a)), colr(r + i + ro)

            Next

            s = s + p2 / 180

        Next

        sx1 = xc: sy1 = yc: sx2 = xc + diag * Cos(.002): sy2 = yc + diag * Sin(.002): sx3 = xc + diag * Cos(p2 / 64 - .002): sy3 = yc + diag * Sin(p2 / 64 - .002)

        For a = p2 / 64 To p2 - p2 / 64 Step p2 / 64

            dx1 = xc: dy1 = yc: dx2 = xc + diag * Cos(a): dy2 = yc + diag * Sin(a): dx3 = xc + diag * Cos(a + p2 / 64): dy3 = yc + diag * Sin(a + p2 / 64)

            _MapTriangle (sx1, sy1)-(sx2, sy2)-(sx3, sy3), source& To(dx1, dy1)-(dx2, dy2)-(dx3, dy3), 0

        Next

        'Line (0, 0)-(xc - 1.5 * yc, _Height), &HFF000000, BF

        'Line (xc + 1.5 * yc, 0)-(_Width, _Height), &HFF000000, BF

        _PutImage (0, 0)-(_Width, _Height), , , (xc - 1.5 * yc, 0)-(xc + 1.5 * yc, _Height)

        toggle = 1 - toggle

        If toggle Then _Display

        '_Limit 80

        ro = ro - 1

    Wend

    If _KeyDown(27) Then System

Wend



Function Plasma~& ()

    cN = cN + .2

    Plasma~& = _RGB32(127 + 127 * Sin(pR * cN), 127 + 127 * Sin(pG * cN), 127 + 127 * Sin(pB * cN))

End Function



Sub resetPlasma ()

    pR = Rnd ^ 2: pG = Rnd ^ 2: pB = Rnd ^ 2

End Sub

Going back to the original, the modifications here were rather simple. Going through your mod of the original, things get complicated fast. LOL!

For this, the original is already set up with all you need. Those black bars on the side are intentional and are created by the two LINE statements.

If you want the center to stretch all the way to the edges, simply remove those LINE statements and use the X/Y reference points to putimage that center to the whole screen. That's it. All that's required.

'Line (0, 0)-(xc - 1.5 * yc, _Height), &HFF000000, BF
'Line (xc + 1.5 * yc, 0)-(_Width, _Height), &HFF000000, BF
_PutImage (0, 0)-(_Width, _Height), , , (xc - 1.5 * yc, 0)-(xc + 1.5 * yc, _Height)

Presto! Whamo! Done!