Hi All,

Since starting the QBJS effort there have been a number of inquiries around support for an offline mode.  For the next release, QBJS will offer offline deployment as a progressive web application (PWA).

You can try this out now at the QBJS dev site:  https://boxgaming.github.io/qbjs/

This change allows you to install QBJS locally directly from the browser.  A new icon will appear in the address bar.  Here's an example of what it looks like in Edge:

   

   

After the install is complete you can then run QBJS in a standalone application window:

   

The best part though is that all of the content needed to run QBJS will be installed on your device.  So you will be able to use it when completely disconnected from the internet.  But you'll still get the best of both worlds as it will download any updates when new releases come out.

This feature will be included in the next release of QBJS along with a number of additional features that are still in progress.  I thought I would go ahead and mention it here as I would love to have any feedback from anyone who is game to try it out in the dev site.  I'd be very interested to hear how it worked (or didn't) for you and what OS/browser combo you have.

A couple of notes:

• The install as app feature is available in most major browsers but for some reason this is not fully supported on Firefox desktop version (although it is on the Android version of Firefox)
  
• On iOS this can be installed by selecting the "Add to Home Screen" option.
  

earliest

So, as the math midget I am, I stumbled upon a way to make 3D looking wire frames using the ATAN2 command which turns "Cartesian coordinates into global coordinates" or so I read. I don't understand why/how the position of the ship on the screen affects the rendering of the eleven 2D points I created. For example, pressing z and putting the ship on the left-hand side of the screen smooshes it flat. Can anyone explain to me on, say, an 8th grade level, what's going on triginomically here? What have I done?! 

OPTION _EXPLICIT

DIM AS INTEGER DTW, DTH: DTW = _DESKTOPWIDTH: DTH = _DESKTOPHEIGHT

SCREEN _NEWIMAGE(DTW, DTH, 32)

_FULLSCREEN _SQUAREPIXELS , _SMOOTH '

_MOUSEHIDE '

TYPE pnt

    x AS SINGLE

    y AS SINGLE '

    ang AS SINGLE '

    radius AS SINGLE '

END TYPE '



DIM pnt(1 TO 13) AS pnt

DIM c AS INTEGER

DIM AS DOUBLE radians

DIM AS INTEGER radius

DIM AS SINGLE adder, sizeFactor, angle, fpChange

DIM AS SINGLE shipX, shipY

DIM AS LONG starScape

DIM AS _UNSIGNED LONG yellow



yellow = _RGB32(249, 244, 17)

shipX = DTW / 2

shipY = DTH / 2



DATA 180,25

'                      1      11 POINTS TO PLAY WITH, 1 is nose point

DATA 265,30

'                      2        DATA = THETA ANGLE, RADIUS - larger radius = closer to viewer

DATA 275,30

'                      3

DATA 340,4

'                      4

DATA 0,5

'                      5

DATA 20,4

'                      6

DATA 85,30

'                      7

DATA 95,30

'                      8

DATA 130,4

'                      9

DATA 230,4

'                      10

DATA 0,0

'                      11

DATA 270,27

'              12, side panel point

DATA 90,27

'              13, other side panel

FOR c = 1 TO UBOUND(pnt) '                      init points array

    READ angle, radius

    pnt(c).ang = angle

    pnt(c).radius = radius

NEXT c



sizeChange 2.5

sizeFactor = 38 '                              start up settings

adder = .25

angle = 270

fpChange = 66 '                                the nose point

pnt(1).radius = pnt(1).radius + fpChange

drawStars



DO

    CLS

    FOR c = 1 TO UBOUND(pnt) '                  rotate ship

        pnt(c).ang = pnt(c).ang + adder

        radians = _D2R(pnt(c).ang)

        pnt(c).x = pnt(c).radius * COS(radians) + shipX '                  atan2 subbed for x/cos value spins in Y axis, neg for left side, pos for right

        pnt(c).y = pnt(c).radius * _ATAN2(pnt(c).x, pnt(c).y) + shipY '  atan2 subbed for y/sin value spins in X axis, upside down, rightside up...

    NEXT c



    _PUTIMAGE , starScape, 0

    ' -----------------------------*******************

    LINE (pnt(1).x, pnt(1).y)-(pnt(2).x, pnt(2).y), yellow '      draw ship

    FOR c = 3 TO 8

        LINE -(pnt(c).x, pnt(c).y), yellow

    NEXT c

    LINE (pnt(8).x, pnt(8).y)-(pnt(1).x, pnt(1).y), yellow

    LINE (pnt(3).x, pnt(3).y)-(pnt(1).x, pnt(1).y), yellow

    LINE (pnt(7).x, pnt(7).y)-(pnt(1).x, pnt(1).y), yellow

    LINE (pnt(2).x, pnt(2).y)-(pnt(10).x, pnt(10).y), yellow

    LINE (pnt(8).x, pnt(8).y)-(pnt(9).x, pnt(9).y), yellow

    LINE (pnt(10).x, pnt(10).y)-(pnt(11).x, pnt(11).y), yellow

    LINE (pnt(9).x, pnt(9).y)-(pnt(11).x, pnt(11).y), yellow

    LINE (pnt(5).x, pnt(5).y)-(pnt(11).x, pnt(11).y), yellow



    IF sizeFactor > 10 AND sizeFactor < 80 AND fpChange > -20 AND shipX = DTW / 2 AND shipY = DTH / 2 THEN

        IF angle < 80 OR angle > 287 THEN PAINT (_WIDTH / 2, _HEIGHT / 2 + 40), _RGB32(250, 50, 150, 60), yellow

        IF angle > 77 AND angle < 255 THEN PAINT (_WIDTH / 2, _HEIGHT / 2 + 40), _RGB32(100, 190, 0, 90), yellow

    END IF

    IF sizeFactor > -50 THEN

        CIRCLE (pnt(12).x, pnt(12).y), 2, _RGB32(249, 249, 0) '    side panel

        PAINT (pnt(12).x, pnt(12).y), _RGB32(255, 0, 0), _RGB32(249, 249, 0)

        CIRCLE (pnt(13).x, pnt(13).y), 2, _RGB32(249, 250, 0)

        PAINT (pnt(13).x, pnt(13).y), _RGB32(255, 0, 0), _RGB32(249, 250, 0)

    END IF

    ' -----------------------------*******************                          user input

    IF _KEYDOWN(122) THEN shipX = shipX - 2

    IF _KEYDOWN(120) THEN shipX = shipX + 2

    IF _KEYDOWN(99) THEN shipY = shipY - 1.554

    IF _KEYDOWN(118) THEN shipY = shipY + 1.554



    IF _KEYDOWN(19200) THEN

        IF fpChange > -500 THEN

            pnt(1).radius = pnt(1).radius - 1 '                                far point changes

            fpChange = fpChange - 1

        END IF

    END IF

    IF _KEYDOWN(19712) THEN

        IF fpChange < 500 THEN

            pnt(1).radius = pnt(1).radius + 1

            fpChange = fpChange + 1

        END IF

    END IF

    IF _KEYDOWN(97) THEN adder = -.5 '                                                                  angle changes

    IF _KEYDOWN(100) THEN adder = .5

    IF _KEYDOWN(18432) THEN IF sizeFactor < 150 THEN sizeChange 1.01: sizeFactor = sizeFactor + .5 '    size changes

    IF _KEYDOWN(20480) THEN IF sizeFactor > -250 THEN sizeChange .99: sizeFactor = sizeFactor - .5

    IF _KEYDOWN(114) THEN adder = .2 '      r to rotate

    IF _KEYDOWN(115) THEN adder = 0 '      s to stop

    angle = angle + adder '                auto-spin

    IF angle > 359 THEN angle = 0 '        mind the angle

    IF angle < 0 THEN angle = 359



    PRINT "Angle:"; INT(angle)

    PRINT "Size Factor:"; sizeFactor

    PRINT "Far Point Change:"; fpChange

    PRINT

    PRINT "up arrow = ENLARGE SHIP"

    PRINT "down arrow = SHRINK SHIP"

    PRINT "left arrow = 'PULL' NOSE POINT"

    PRINT "right arrow = 'PUSH' NOSE POINT"

    PRINT "d = spin fast clockwise"

    PRINT "a = spin fast counterclockwise"

    PRINT "r = back to slow rotate"

    PRINT "s = stop rotation"

    PRINT "z = LEFT"

    PRINT "x = RIGHT"

    PRINT "c = UP"

    PRINT "v = DOWN"

    _DISPLAY

    _LIMIT 200

LOOP UNTIL _KEYDOWN(27)

SYSTEM

' ------------------------------------

SUB sizeChange (r AS SINGLE)

    DIM c AS INTEGER

    SHARED AS pnt pnt()

    FOR c = 1 TO UBOUND(pnt)

        pnt(c).radius = pnt(c).radius * r

    NEXT c

END SUB

' ------------------------------------

SUB drawStars () '                              starscape backdrop

    DIM c AS INTEGER

    DIM AS LONG virtual

    SHARED AS LONG starScape

    virtual = _NEWIMAGE(1280, 720, 32) '

    _DEST virtual

    c = 0

    DO

        c = c + 1

        PSET ((INT(RND * _WIDTH)), INT(RND * _HEIGHT)), _RGB32(200) '              whites

    LOOP UNTIL c = 2000 ' was 3600

    c = 0

    DO

        c = c + 1

        PSET ((INT(RND * _WIDTH)), INT(RND * _HEIGHT)), _RGB32(70) '                grays

    LOOP UNTIL c = 6000 ' was 3600

    c = 0

    DO

        c = c + 1

        PSET ((INT(RND * _WIDTH)), INT(RND * _HEIGHT)), _RGB32(255, 67, 55, 124) '  reddies

        DRAW "S2U1R1D1L1"

    LOOP UNTIL c = 26

    c = 0

    DO

        c = c + 1

        PSET ((INT(RND * _WIDTH)), INT(RND * _HEIGHT)), _RGB32(0, 255, 0, 116) '    greenies

        DRAW "S2U1R1D1L1"

    LOOP UNTIL c = 86

    c = 0

    DO

        c = c + 1

        PRESET ((INT(RND * _WIDTH)), INT(RND * _HEIGHT)), _RGB32(255, 255, 183, 120) '  big yellows

        DRAW "S4U1R1D1L1"

    LOOP UNTIL c = 130

    starScape = _COPYIMAGE(virtual, 32) ' software image

    _DEST 0

    _FREEIMAGE virtual

END SUB

' -----------------------------------------

I highly prefer forums over chat rooms such as Discord, but there is one bad habit I don't miss from the message board era: excessive quotations. Here's a screenshot to provide an example, not with intent to pick on anyone:



Though the screenshot is on a cell phone which exacerbates the issue, "mobile" traffic is a substantial amount of Web traffic, so it seems ridiculous for a post to use an entire screen length. The actual content of the post is one sentence! Even on a laptop screen or external monitor, it's a slight irritation scrolling past multiple duplicates of both posts and code as one works their way through reading a thread.

Here's my etiquette: If I'm responding to the newest post in the thread, I don't think there is a need to quote at all. When I do quote, I try to reduce it to the specific part of the message being replied to. I cannot think of a common purpose to nest multiple quotes within each other. You can click the green arrow icon () next to a person's quote to revisit their post in full when additional context is needed.

The MyBB software provides a built-in way to eliminate excessive quoting by setting a value for Maximum Nested Quote Tags. It should be found here if they have not changed their UI: Admin Control Panel -> Configuration -> Settings -> Posting

This is my first game. I make it with help from QB64_GPT.

' Here is my first game created with help QB64_GPT.

' Name app "SokoGus v0.01"

' Created by Gus and QB64_GPT 07-03-2024.



OPTION _EXPLICIT



CONST MapWidth = 30

CONST MapHeight = 12

CONST TileWidth = 64

CONST TileHeight = 64



TYPE Tile

    Symbol AS STRING * 1

    IsBox AS INTEGER

    IsGoal AS INTEGER

    HasBox AS INTEGER

    HasPlayer AS INTEGER

END TYPE



TYPE Box

    X AS INTEGER

    Y AS INTEGER

    Symbol AS STRING * 1

END TYPE



DIM SHARED Boxes(6) AS Box

DIM SHARED key$

DIM SHARED levelMap(1 TO 25) AS STRING * 25

DIM SHARED tileSymbol AS STRING

DIM SHARED MapTiles(MapWidth, MapHeight) AS Tile

DIM SHARED PlayerX, PlayerY

DIM SHARED NumGoals, GoalsCompleted

DIM SHARED GoalsCoveredCount AS INTEGER

DIM SHARED prevX AS INTEGER

DIM SHARED prevY AS INTEGER

DIM SHARED newX AS INTEGER

DIM SHARED newY AS INTEGER

DIM SHARED newBoxX AS INTEGER

DIM SHARED newBoxY AS INTEGER

DIM SHARED fontfile$

DIM SHARED f&

DIM SHARED ascIIcode AS SINGLE

DIM SHARED unicode

DIM SHARED currentTile AS Tile

DIM SHARED boxTile AS Tile

DIM SHARED newTile AS Tile



' Icons

DIM SHARED playerIcon AS LONG

DIM SHARED boxIcon AS LONG

DIM SHARED goalIcon AS LONG

DIM SHARED emptyTileIcon AS LONG

DIM SHARED boxOnGoalIcon AS LONG

DIM SHARED playerOnGoalIcon AS LONG

DIM SHARED wallIcon AS LONG



DIM SHARED folder$

folder$ = "D:\qb64pe\Assets\"



SCREEN _NEWIMAGE(1264, 878, 32) ' Create new screen



' Load a font that supports Greek characters

fontfile$ = "C:\windows\fonts\lucon.ttf"

f& = _LOADFONT(fontfile$, 20, "MONOSPACE")

_FONT f&



' Load icons and check for errors

playerIcon = _LOADIMAGE(folder$ + "player.png", 32)



boxIcon = _LOADIMAGE(folder$ + "box.png", 32)



goalIcon = _LOADIMAGE(folder$ + "goal.png", 32)



emptyTileIcon = _LOADIMAGE(folder$ + "empty.png", 32)



boxOnGoalIcon = _LOADIMAGE(folder$ + "boxOnGoal.png", 32)



playerOnGoalIcon = _LOADIMAGE(folder$ + "playerOnGoal.png", 32)



wallIcon = _LOADIMAGE(folder$ + "wall.png", 32)





' Initialize GoalsCoveredCount to 0

GoalsCoveredCount = 0



' Initialize the game

InitializeGame



' Load level 1

LoadLevel 1



DO

    _LIMIT 60

    DrawMap

    _DISPLAY



    DO

        key$ = INKEY$

        IF LEN(key$) > 0 THEN EXIT DO

    LOOP



    IF key$ = CHR$(27) THEN EXIT DO ' Exit on Escape key



    newX = PlayerX

    newY = PlayerY



    SELECT CASE UCASE$(key$)

        CASE "W", CHR$(0) + CHR$(72) ' Up arrow or "w" key

            newY = PlayerY - 1

        CASE "S", CHR$(0) + CHR$(80) ' Down arrow or "s" key

            newY = PlayerY + 1

        CASE "A", CHR$(0) + CHR$(75) ' Left arrow or "a" key

            newX = PlayerX - 1

        CASE "D", CHR$(0) + CHR$(77) ' Right arrow or "d" key

            newX = PlayerX + 1

    END SELECT



    ' Check player movement

    IF newX >= 1 AND newX <= MapWidth AND newY >= 1 AND newY <= MapHeight THEN

        IF MapTiles(newX, newY).Symbol = " " OR MapTiles(newX, newY).Symbol = "." THEN

            MovePlayer newX, newY

        ELSEIF MapTiles(newX, newY).Symbol = "$" OR MapTiles(newX, newY).Symbol = "*" THEN

            newBoxX = newX + (newX - PlayerX)

            newBoxY = newY + (newY - PlayerY)

            IF newBoxX >= 1 AND newBoxX <= MapWidth AND newBoxY >= 1 AND newBoxY <= MapHeight THEN

                IF MapTiles(newBoxX, newBoxY).Symbol = " " OR MapTiles(newBoxX, newBoxY).Symbol = "." THEN

                    MoveBox newX, newY, newBoxX, newBoxY

                    MovePlayer newX, newY

                END IF

            END IF

        END IF

    END IF



LOOP UNTIL GoalsCompleted = NumGoals



CLS

PRINT "Congratulations! You completed the level."

END



' Subroutine to draw the map

SUB DrawMap

    DIM x AS INTEGER

    DIM y AS INTEGER

    CLS

    FOR y = 1 TO MapHeight

        FOR x = 1 TO MapWidth

            SELECT CASE MapTiles(x, y).Symbol

                CASE "@"

                    IF playerIcon <> -1 THEN _PUTIMAGE (x * TileWidth, y * TileHeight), playerIcon

                CASE "$"

                    IF MapTiles(x, y).IsGoal THEN

                        IF boxOnGoalIcon <> -1 THEN _PUTIMAGE (x * TileWidth, y * TileHeight), boxOnGoalIcon

                    ELSE

                        IF boxIcon <> -1 THEN _PUTIMAGE (x * TileWidth, y * TileHeight), boxIcon

                    END IF

                CASE "."

                    IF goalIcon <> -1 THEN _PUTIMAGE (x * TileWidth, y * TileHeight), goalIcon

                CASE " "

                    IF emptyTileIcon <> -1 THEN _PUTIMAGE (x * TileWidth, y * TileHeight), emptyTileIcon

                CASE "+"

                    IF playerOnGoalIcon <> -1 THEN _PUTIMAGE (x * TileWidth, y * TileHeight), playerOnGoalIcon

                CASE "*"

                    IF boxOnGoalIcon <> -1 THEN _PUTIMAGE (x * TileWidth, y * TileHeight), boxOnGoalIcon

                CASE "#"

                    IF wallIcon <> -1 THEN _PUTIMAGE (x * TileWidth, y * TileHeight), wallIcon

            END SELECT

        NEXT x

    NEXT y

    GreekChange

    _PRINTSTRING (10, 10), "Goals completed: " + STR$(GoalsCoveredCount) + "/" + STR$(NumGoals)

    EnglChange

END SUB



' Subroutine to move the player

SUB MovePlayer (newX, newY)

    prevX = PlayerX

    prevY = PlayerY



    ' Update the tile the player is leaving

    currentTile = MapTiles(prevX, prevY)

    IF currentTile.IsGoal = 1 THEN

        MapTiles(prevX, prevY).Symbol = "."

    ELSE

        MapTiles(prevX, prevY).Symbol = " "

    END IF



    ' Move the player to the new position

    PlayerX = newX

    PlayerY = newY



    ' Update the tile the player is moving to

    currentTile = MapTiles(PlayerX, PlayerY)

    IF currentTile.IsGoal = 1 THEN

        MapTiles(PlayerX, PlayerY).Symbol = "+"

    ELSE

        MapTiles(PlayerX, PlayerY).Symbol = "@"

    END IF

END SUB



' Subroutine to move a box

SUB MoveBox (boxX AS INTEGER, boxY AS INTEGER, newBoxX AS INTEGER, newBoxY AS INTEGER)

    DIM i AS INTEGER

    boxTile = MapTiles(boxX, boxY)

    newTile = MapTiles(newBoxX, newBoxY)



    IF newTile.Symbol = "." OR newTile.Symbol = " " THEN

        ' Update the tile the box is leaving

        IF boxTile.IsGoal = 1 THEN

            MapTiles(boxX, boxY).Symbol = "."

        ELSE

            MapTiles(boxX, boxY).Symbol = " "

        END IF



        ' Update the tile the box is moving to

        MapTiles(newBoxX, newBoxY).Symbol = "$"

        MapTiles(newBoxX, newBoxY).HasBox = 1

        MapTiles(boxX, boxY).HasBox = 0



        ' Update the position of the box

        FOR i = 1 TO 6

            IF Boxes(i).X = boxX AND Boxes(i).Y = boxY THEN

                Boxes(i).X = newBoxX

                Boxes(i).Y = newBoxY

                EXIT FOR

            END IF

        NEXT i



        ' Update the goals covered

        IF MapTiles(newBoxX, newBoxY).IsGoal = 1 THEN

            GoalsCoveredCount = GoalsCoveredCount + 1

        END IF



        IF MapTiles(boxX, boxY).IsGoal = 1 THEN

            GoalsCoveredCount = GoalsCoveredCount - 1

        END IF



        ' Check if all goals are covered

        IF GoalsCoveredCount = NumGoals THEN

            GoalsCompleted = GoalsCompleted + 1

        END IF

    END IF

END SUB



' Subroutine to initialize the game

SUB InitializeGame ()

    DIM y AS INTEGER

    DIM x AS INTEGER

    NumGoals = 0 ' Initialize the goals

    GoalsCompleted = 0

    PlayerX = 14

    PlayerY = 4

    MapTiles(PlayerX, PlayerY).Symbol = "@"



    FOR y = 1 TO MapHeight

        FOR x = 1 TO MapWidth

            MapTiles(x, y).Symbol = " "

            MapTiles(x, y).IsGoal = 0

            MapTiles(x, y).IsBox = 0

        NEXT x

    NEXT y

END SUB



' Subroutine to load a level

SUB LoadLevel (levelNumber AS INTEGER)

    DIM row, col, i

    levelMap(1) = "  ####"

    levelMap(2) = " ##  #########"

    levelMap(3) = " #           ###"

    levelMap(4) = " # **********@ #"

    levelMap(5) = "## *        .  #"

    levelMap(6) = "#  *#######**$##"

    levelMap(7) = "#             #"

    levelMap(8) = "############  #"

    levelMap(9) = "           ####"

    'levelMap(1) = "      #####"

    'levelMap(2) = "      #  #"

    'levelMap(3) = "      #$  #"

    'levelMap(4) = "    ###  $##"

    'levelMap(5) = "    #  $ $ #"

    'levelMap(6) = "##### # ## # ######"

    'levelMap(7) = "#    # ## ###  ..#"

    'levelMap(8) = "# $ $          ..#"

    'levelMap(9) = "##### ## # ###  ..#"

    'levelMap(10) = "    # ## ##########"

    'levelMap(11) = "    #    #"

    'levelMap(12) = "    ######"





    NumGoals = 0 ' Reset total goals

    GoalsCoveredCount = 0 ' Reset goals covered count



    FOR row = 1 TO MapHeight

        FOR col = 1 TO MapWidth

            tileSymbol = MID$(levelMap(row), col, 1)



            MapTiles(col, row).Symbol = tileSymbol

            MapTiles(col, row).IsBox = 0

            MapTiles(col, row).IsGoal = 0



            IF tileSymbol = "$" THEN

                FOR i = 1 TO 6

                    IF Boxes(i).X = 0 AND Boxes(i).Y = 0 THEN

                        Boxes(i).Symbol = "$"

                        Boxes(i).X = col

                        Boxes(i).Y = row

                        EXIT FOR

                    END IF

                NEXT i

                MapTiles(col, row).IsBox = 1

                MapTiles(col, row).HasBox = 1

            END IF



            IF tileSymbol = "." OR tileSymbol = "*" THEN

                MapTiles(col, row).IsGoal = 1

                NumGoals = NumGoals + 1 ' Update total goals

            END IF



            ' Check if box is on a goal

            IF tileSymbol = "*" THEN

                GoalsCoveredCount = GoalsCoveredCount + 1 ' Update goals covered count

                MapTiles(col, row).HasBox = 1

            END IF

        NEXT col

    NEXT row

END SUB



' Subroutine to switch to Greek characters

SUB GreekChange

    RESTORE GreekUnicodeMap

    FOR ascIIcode = 128 TO 255

        READ unicode

        _MAPUNICODE unicode TO ascIIcode

    NEXT



    GreekUnicodeMap:

    'Microsoft_windows_cp1253

    DATA 8364,0,8218,402,8222,8230,8224,8225,0,8240,0,8249,0,0,0,0

    DATA 0,8216,8217,8220,8221,8226,8211,8212,0,8482,0,8250,0,0,0,0

    DATA 160,901,902,163,164,165,166,167,168,169,0,171,172,173,174,8213

    DATA 176,177,178,179,900,181,182,183,904,905,906,187,908,189,910,911

    DATA 912,913,914,915,916,917,918,919,920,921,922,923,924,925,926,927

    DATA 928,929,0,931,932,933,934,935,936,937,938,939,940,941,942,943

    DATA 944,945,946,947,948,949,950,951,952,953,954,955,956,957,958,959

    DATA 960,961,962,963,964,965,966,967,968,969,970,971,972,973,974,0



END SUB



' Subroutine to switch to English characters

SUB EnglChange



    RESTORE EnglUnicodeMap

    FOR ascIIcode = 128 TO 255

        READ unicode

        _MAPUNICODE unicode TO ascIIcode

    NEXT



    EnglUnicodeMap:

    'Microsoft_pc_cp437

    DATA 199,252,233,226,228,224,229,231,234,235,232,239,238,236,196,197

    DATA 201,230,198,244,246,242,251,249,255,214,220,162,163,165,8359,402

    DATA 225,237,243,250,241,209,170,186,191,8976,172,189,188,161,171,187

    DATA 9617,9618,9619,9474,9508,9569,9570,9558,9557,9571,9553,9559,9565,9564,9563,9488

    DATA 9492,9524,9516,9500,9472,9532,9566,9567,9562,9556,9577,9574,9568,9552,9580,9575

    DATA 9576,9572,9573,9561,9560,9554,9555,9579,9578,9496,9484,9608,9604,9612,9616,9600

    DATA 945,223,915,960,931,963,181,964,934,920,937,948,8734,966,949,8745

    DATA 8801,177,8805,8804,8992,8993,247,8776,176,8729,183,8730,8319,178,9632,160



END SUB

Hello,

I have used WiringPi in freebasic to access GPIO pins on the RaspberryPI 3 Model B+

To give an idea of WiringPI https://pinout.xyz/pinout/wiringpi

WiringPI is a c-lib


I tried to use this lib in QB64 but I get it not working.

Reason I want use this lib because it can read the value (tension) on a gpio pin.

(I use also the RASPI-GPIO utility via the QB64 shell statement, this works fin in QB64,
  but this utility can not read the value of a gpio-pin)

I did some little test with the "Library" statement of QB64 but always run in errors.

Has anybody got working WiringPI or 100% c-lib in QB64?
if yes: Would You publisch the initial code to use such library of a c-lib?

Rudy M

This error reported in QB45 has been there forever:

So, using arrays as record elements is not possible in QB. OK, but declaring record arrays is also possible in QB.

I've tried this according to the QBasic manual, only a rudimentary guide, but something isn't working. The program runs without errors, but there is no meaningful output. I'm thinking wrong.

Type Motorrad

  Modell As String * 30

  Kilowatt As Double

  Preis As Double

End Type



Dim MotorradMarken(2) As Motorrad



Dim As Integer anzahl, satzNummer



satzNummer = 1

Do

  Input "Modell    : ", Motorrad.Modell

  Input "Kilowatt  : ", Motorrad.Kilowatt

  Input "Preis      : ", Motorrad.Preis



  satzNummer = satzNummer + 1

Loop Until satzNummer = 2



For anzahl = 1 To satzNummer

  Print MotorradMarken(anzahl).Modell

  Print MotorradMarken(anzahl).Kilowatt

  Print MotorradMarken(anzahl).Preis

Next

Onwards and backwards, as we're now down to the new version 3.4+ keywords!   To start with, let's just start at the top of the list and discuss _NotifyPopUp.

Wiki entry: https://qb64phoenix.com/qb64wiki/index.php/NOTIFYPOPUP
Syntax:    _NOTIFYPOPUP [title$][, message$][, iconType$]

Not at all like our last keyword (BACK!  BACK, EVIL _UCHARPOS!! BACK, I SAY!!), this one is rather simple to make use of and understand. 

A simple SUB, this command will sent one of those annoying little pop-up notifications to your PC, that we all love to hate.  You know the ones I'm talking about -- those little square boxes that usually pop up over in some corner of the screen saying junk like, "Your Firewall is Turned Off.  Do you want to fix it now?".   Or, "We've discovered an update for Spammy Spam-Spam!  Would you like to enable it now?"  Or, "Download finished at 1:13:47AM."

Yeah... This creates THOSE annoying little notification pop-ups. 

Usage is simple enough that it's almost a waste to go over it.   Call the command, supply it a few parameters.  Presto -- done!!

So what is the command and those parameters??

_NOTIFYPOPUP [title$][, message$][, iconType$]

_NOTIFYPOPUP -- the name of the command!   (Phew!  That was hard to explain!)
title$  -- the title that appears at the top of the notification.
message$ --   the body of text that makes up the message for the notification.
icontype$ -- "info", "error", ot "warning".   Choose from one of those three so your notification will have the corresponding gpahiic stamped on it.